Text file src/runtime/cgo/asm_unix_386.s

     1  // Copyright 2026 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && 386
     6  
     7  #include "go_asm.h"
     8  #include "textflag.h"
     9  
    10  // cgoCallTrampoline is called by runtime.asmcgocall or runtime.asmcgocall_no_g
    11  // using the System V i386 C ABI with 4(SP) pointing to a cgoCallFrame.
    12  // Both callers 16-byte align SP before CALL, so SP%16 == 12 on entry.
    13  TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
    14  	PUSHL	BP
    15  	MOVL	SP, BP
    16  	// 4B saved BX + 12B padding + 24B outgoing args; keeps SP 16-byte aligned.
    17  	ADJSP	$40
    18  	MOVL	BX, -4(BP)
    19  	MOVL	8(BP), BX
    20  	MOVL	cgoCallFrame_a0(BX), AX
    21  	MOVL	AX, 0(SP)
    22  	MOVL	cgoCallFrame_a1(BX), AX
    23  	MOVL	AX, 4(SP)
    24  	MOVL	cgoCallFrame_a2(BX), AX
    25  	MOVL	AX, 8(SP)
    26  	MOVL	cgoCallFrame_a3(BX), AX
    27  	MOVL	AX, 12(SP)
    28  	MOVL	cgoCallFrame_a4(BX), AX
    29  	MOVL	AX, 16(SP)
    30  	MOVL	cgoCallFrame_a5(BX), AX
    31  	MOVL	AX, 20(SP)
    32  	MOVL	cgoCallFrame_fn(BX), AX
    33  	CALL	AX
    34  	MOVL	AX, cgoCallFrame_r1(BX)
    35  	XORL	AX, AX
    36  	MOVL	-4(BP), BX
    37  	ADJSP	$-40
    38  	POPL	BP
    39  	RET
    40  
    41  #define CGO_PROLOGUE \
    42  	CLD; \
    43  	PUSHL	BP; \
    44  	PUSHL	BX; \
    45  	PUSHL	SI; \
    46  	PUSHL	DI
    47  
    48  #define CGO_EPILOGUE \
    49  	POPL	DI; \
    50  	POPL	SI; \
    51  	POPL	BX; \
    52  	POPL	BP
    53  
    54  TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
    55  	LEAL	·runtime_init_done(SB), AX
    56  	MOVL	(AX), AX
    57  	CMPL	AX, $2
    58  	JNE	slow
    59  	LEAL	·cgo_context_function(SB), AX
    60  	MOVL	(AX), AX
    61  	TESTL	AX, AX
    62  	JNE	slow
    63  	RET
    64  slow:
    65  	CGO_PROLOGUE
    66  	ADJSP	$4
    67  	CALL	·cgoWaitRuntimeInitDone(SB)
    68  	MOVL	0(SP), AX
    69  	ADJSP	$-4
    70  	CGO_EPILOGUE
    71  	RET
    72  
    73  TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
    74  	MOVL	4(SP), AX
    75  	TESTL	AX, AX
    76  	JEQ	done
    77  	CGO_PROLOGUE
    78  	ADJSP	$4
    79  	MOVL	AX, 0(SP)
    80  	CALL	·cgoReleaseContext(SB)
    81  	ADJSP	$-4
    82  	CGO_EPILOGUE
    83  done:
    84  	RET
    85  
    86  TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
    87  	PUSHL	BP
    88  	MOVL	SP, BP
    89  	SUBL	$20, SP
    90  	ANDL	$~15, SP
    91  	// BX is callee-saved in C, and -dynlink code clobbers it.
    92  	MOVL	BX, -4(BP)
    93  	MOVL	8(BP), AX
    94  	MOVL	$0, 0(SP)
    95  	MOVL	AX, 4(SP)
    96  	MOVL	$0, 8(SP)
    97  	MOVL	$0, 12(SP)
    98  	CALL	crosscall2(SB)
    99  	MOVL	-4(BP), BX
   100  	MOVL	BP, SP
   101  	POPL	BP
   102  	RET
   103  
   104  TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
   105  	CGO_PROLOGUE
   106  	MOVL	20(SP), AX
   107  	ADJSP	$4
   108  	MOVL	AX, 0(SP)
   109  	CALL	·threadentry(SB)
   110  	ADJSP	$-4
   111  	CGO_EPILOGUE
   112  	XORL	AX, AX
   113  	RET
   114  
   115  TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
   116  	CGO_PROLOGUE
   117  	ADJSP	$16
   118  	MOVL	36(SP), AX
   119  	MOVL	AX, 0(SP)
   120  	MOVL	40(SP), AX
   121  	MOVL	AX, 4(SP)
   122  	MOVL	44(SP), AX
   123  	MOVL	AX, 8(SP)
   124  	MOVL	48(SP), AX
   125  	MOVL	AX, 12(SP)
   126  	CALL	·cgoInit(SB)
   127  	ADJSP	$-16
   128  	CGO_EPILOGUE
   129  	RET
   130  GLOBL _cgo_init(SB), NOPTR, $4
   131  DATA _cgo_init+0(SB)/4, $x_cgo_init<>(SB)
   132  

View as plain text