Text file src/runtime/cgo/asm_unix_amd64.s

     1  // Copyright 2026 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && amd64
     6  
     7  #include "go_asm.h"
     8  #include "textflag.h"
     9  #include "abi_amd64.h"
    10  
    11  // cgoCallTrampoline is called by runtime.asmcgocall (or runtime.cgocall)
    12  // using the System V AMD64 C ABI with DI pointing to a cgoCallFrame.
    13  // The target function may be variadic: AX is cleared to tell it that no
    14  // arguments are passed in vector registers.
    15  TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
    16  	PUSHQ	BP
    17  	MOVQ	SP, BP
    18  	PUSHQ	BX
    19  	ADJSP	$8		// align SP before CALL and record the change for unwinding
    20  	MOVQ	DI, BX
    21  	MOVQ	cgoCallFrame_fn(DI), R11
    22  	MOVQ	cgoCallFrame_a1(DI), SI
    23  	MOVQ	cgoCallFrame_a2(DI), DX
    24  	MOVQ	cgoCallFrame_a3(DI), CX
    25  	MOVQ	cgoCallFrame_a4(DI), R8
    26  	MOVQ	cgoCallFrame_a5(DI), R9
    27  	MOVQ	cgoCallFrame_a0(DI), DI
    28  	XORL	AX, AX		// vararg: say "no float args"
    29  	CALL	R11
    30  	MOVQ	AX, cgoCallFrame_r1(BX)
    31  	XORL	AX, AX
    32  	ADJSP	$-8
    33  	POPQ	BX
    34  	POPQ	BP
    35  	RET
    36  
    37  TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
    38  	// Use LEAQ to avoid clobbering R15 (callee-saved in the C ABI)
    39  	// when dynamic linking rewrites global accesses via the GOT.
    40  	LEAQ	·runtime_init_done(SB), AX
    41  	MOVL	(AX), AX
    42  	CMPL	AX, $2
    43  	JNE	slow
    44  	LEAQ	·cgo_context_function(SB), AX
    45  	MOVQ	(AX), AX
    46  	TESTQ	AX, AX
    47  	JNZ	callctx
    48  	RET
    49  slow:
    50  	PUSH_REGS_HOST_TO_ABI0()
    51  	ADJSP	$8
    52  	CALL	·cgoWaitRuntimeInit(SB)
    53  	MOVQ	0(SP), AX
    54  	ADJSP	$-8
    55  	POP_REGS_HOST_TO_ABI0()
    56  	TESTQ	AX, AX
    57  	JNZ	callctx
    58  	RET
    59  callctx:
    60  	JMP	·x_cgo_call_context(SB)
    61  
    62  // x_cgo_call_context calls the registered cgo context function (passed in AX).
    63  // cmd/link emits static unwind info matching the standard frame-pointer prologue
    64  // so callbacks using _Unwind_Backtrace unwind cleanly into the C caller.
    65  TEXT ·x_cgo_call_context(SB),NOSPLIT|NOFRAME,$0-0
    66  	PUSHQ	BP
    67  	MOVQ	SP, BP
    68  	SUBQ	$16, SP
    69  
    70  	MOVQ	$0, 0(SP)	// arg.context = 0
    71  	MOVQ	SP, DI		// &arg
    72  	CALL	AX
    73  
    74  	MOVQ	0(SP), AX	// return arg.context
    75  	MOVQ	BP, SP
    76  	POPQ	BP
    77  	RET
    78  
    79  TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
    80  	TESTQ	DI, DI
    81  	JEQ	done
    82  	PUSH_REGS_HOST_TO_ABI0()
    83  	ADJSP	$8
    84  	MOVQ	DI, 0(SP)
    85  	CALL	·cgoReleaseContext(SB)
    86  	ADJSP	$-8
    87  	POP_REGS_HOST_TO_ABI0()
    88  done:
    89  	RET
    90  
    91  TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
    92  	MOVQ	DI, SI
    93  	XORL	DI, DI
    94  	XORL	CX, CX
    95  	JMP	crosscall2(SB)
    96  
    97  TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
    98  	PUSH_REGS_HOST_TO_ABI0()
    99  	XORPS	X15, X15
   100  #ifndef GOAMD64_v3
   101  #ifndef GOAMD64_v4
   102  	CMPB	internal∕cpu·X86+const_offsetX86HasAVX(SB), $1
   103  	JNE	2(PC)
   104  #endif
   105  #endif
   106  	VXORPS	X15, X15, X15
   107  	XORQ	R14, R14
   108  	MOVQ	DI, AX
   109  	CALL	·threadentry<ABIInternal>(SB)
   110  	POP_REGS_HOST_TO_ABI0()
   111  	XORL	AX, AX
   112  	RET
   113  
   114  TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
   115  	PUSH_REGS_HOST_TO_ABI0()
   116  	ADJSP	$32
   117  	MOVQ	DI, 0(SP)
   118  	MOVQ	SI, 8(SP)
   119  	MOVQ	DX, 16(SP)
   120  	MOVQ	CX, 24(SP)
   121  	CALL	·cgoInit(SB)
   122  	ADJSP	$-32
   123  	POP_REGS_HOST_TO_ABI0()
   124  	RET
   125  
   126  GLOBL _cgo_init(SB), NOPTR, $8
   127  DATA _cgo_init+0(SB)/8, $x_cgo_init<>(SB)
   128  
   129  // x_cgo_callers is jumped to from runtime.cgoSigtramp on the signal stack.
   130  // cmd/link emits static unwind info matching the standard frame-pointer prologue
   131  // so traceback callbacks unwind cleanly into the OS signal trampoline.
   132  TEXT ·x_cgo_callers(SB),NOSPLIT|NOFRAME,$0-0
   133  	PUSHQ	BP
   134  	MOVQ	SP, BP
   135  	SUBQ	$64, SP
   136  
   137  	MOVQ	$0, 0(SP)	// arg.context = 0
   138  	MOVQ	DX, 8(SP)	// arg.sigContext = context
   139  	MOVQ	R8, 16(SP)	// arg.buf = cgoCallers
   140  	MOVQ	$32, 24(SP)	// arg.max = 32
   141  
   142  	MOVQ	DI, 32(SP)	// save sig
   143  	MOVQ	SI, 40(SP)	// save info
   144  	MOVQ	DX, 48(SP)	// save context
   145  	MOVQ	R9, 56(SP)	// save sigtramp
   146  
   147  	MOVQ	SP, DI		// &arg
   148  	CALL	CX		// (*cgoTraceback)(&arg)
   149  
   150  	MOVQ	32(SP), DI	// restore sig
   151  	MOVQ	40(SP), SI	// restore info
   152  	MOVQ	48(SP), DX	// restore context
   153  	MOVQ	56(SP), AX	// restore sigtramp
   154  
   155  	MOVQ	BP, SP
   156  	POPQ	BP
   157  	JMP	AX		// sigtramp(sig, info, context)
   158  
   159  GLOBL _cgo_callers(SB), NOPTR, $8
   160  DATA _cgo_callers+0(SB)/8, $·x_cgo_callers(SB)
   161  

View as plain text