Text file
src/runtime/cgo/asm_unix_arm.s
1 // Copyright 2026 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && arm
6
7 #include "go_asm.h"
8 #include "textflag.h"
9
10 // cgoCallTrampoline is called by runtime.asmcgocall or runtime.asmcgocall_no_g
11 // using the ARM EABI (AAPCS) with R0 pointing to a cgoCallFrame.
12 TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
13 SUB $16, R13
14 MOVW R4, 8(R13)
15 MOVW R14, 12(R13)
16 MOVW R0, R4
17 MOVW cgoCallFrame_a4(R4), R1
18 MOVW R1, 0(R13)
19 MOVW cgoCallFrame_a5(R4), R1
20 MOVW R1, 4(R13)
21 MOVW cgoCallFrame_fn(R4), R12
22 MOVW cgoCallFrame_a0(R4), R0
23 MOVW cgoCallFrame_a1(R4), R1
24 MOVW cgoCallFrame_a2(R4), R2
25 MOVW cgoCallFrame_a3(R4), R3
26 BL (R12)
27 MOVW R0, cgoCallFrame_r1(R4)
28 MOVW $0, R0
29 MOVW 8(R13), R4
30 MOVW 12(R13), R14
31 ADD $16, R13
32 RET
33
34 #define CGO_PROLOGUE(skipfp) \
35 SUB $120, R13; \
36 MOVW R4, 20(R13); \
37 MOVW R5, 24(R13); \
38 MOVW R6, 28(R13); \
39 MOVW R7, 32(R13); \
40 MOVW R8, 36(R13); \
41 MOVW R9, 40(R13); \
42 MOVW g, 44(R13); \
43 MOVW R11, 48(R13); \
44 MOVW R14, 52(R13); \
45 MOVB runtime·goarmsoftfp(SB), R11; \
46 CMP $0, R11; \
47 BNE skipfp; \
48 MOVD F8, 56(R13); \
49 MOVD F9, 64(R13); \
50 MOVD F10, 72(R13); \
51 MOVD F11, 80(R13); \
52 MOVD F12, 88(R13); \
53 MOVD F13, 96(R13); \
54 MOVD F14, 104(R13); \
55 MOVD F15, 112(R13); \
56 skipfp: \
57 MOVW $0, g
58
59 #define CGO_EPILOGUE(skipfp) \
60 MOVB runtime·goarmsoftfp(SB), R11; \
61 CMP $0, R11; \
62 BNE skipfp; \
63 MOVD 56(R13), F8; \
64 MOVD 64(R13), F9; \
65 MOVD 72(R13), F10; \
66 MOVD 80(R13), F11; \
67 MOVD 88(R13), F12; \
68 MOVD 96(R13), F13; \
69 MOVD 104(R13), F14; \
70 MOVD 112(R13), F15; \
71 skipfp: \
72 MOVW 20(R13), R4; \
73 MOVW 24(R13), R5; \
74 MOVW 28(R13), R6; \
75 MOVW 32(R13), R7; \
76 MOVW 36(R13), R8; \
77 MOVW 40(R13), R9; \
78 MOVW 44(R13), g; \
79 MOVW 48(R13), R11; \
80 MOVW 52(R13), R14; \
81 ADD $120, R13
82
83 TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
84 // Save R11 (REGTMP) in caller-saved R12: GOT loads under -dynlink
85 // clobber R11, which is callee-saved in the ARM EABI.
86 MOVW R11, R12
87 MOVW $·runtime_init_done(SB), R1
88 MOVW (R1), R1
89 CMP $2, R1
90 BNE slow
91 // Make the load of runtime_init_done an acquire load, as
92 // internal/runtime/atomic.Load does. DMB requires ARMv7;
93 // use the slow path on older processors.
94 // Load runtime·goarm through R2: with -dynlink, a direct load
95 // would use R9, which is callee-saved in the ARM EABI.
96 MOVW $runtime·goarm(SB), R2
97 MOVB (R2), R2
98 CMP $7, R2
99 BLT slow
100 DMB MB_ISH
101 MOVW $·cgo_context_function(SB), R0
102 MOVW (R0), R0
103 CMP $0, R0
104 BNE slow
105 MOVW R12, R11
106 RET
107 slow:
108 MOVW R12, R11
109 CGO_PROLOGUE(wait_skipfpsave)
110 BL ·cgoWaitRuntimeInitDone(SB)
111 MOVW 4(R13), R0
112 CGO_EPILOGUE(wait_skipfprest)
113 RET
114
115 TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
116 CMP $0, R0
117 BEQ done
118 CGO_PROLOGUE(rel_skipfpsave)
119 MOVW R0, 4(R13)
120 BL ·cgoReleaseContext(SB)
121 CGO_EPILOGUE(rel_skipfprest)
122 done:
123 RET
124
125 TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
126 MOVW R0, R1
127 MOVW $0, R0
128 MOVW $0, R3
129 B crosscall2(SB)
130
131 TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
132 CGO_PROLOGUE(thr_skipfpsave)
133 MOVW R0, 4(R13)
134 BL ·threadentry(SB)
135 CGO_EPILOGUE(thr_skipfprest)
136 MOVW $0, R0
137 RET
138
139 TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
140 CGO_PROLOGUE(init_skipfpsave)
141 MOVW R0, 4(R13)
142 MOVW R1, 8(R13)
143 MOVW R2, 12(R13)
144 MOVW R3, 16(R13)
145 BL ·cgoInit(SB)
146 CGO_EPILOGUE(init_skipfprest)
147 RET
148 GLOBL _cgo_init(SB), NOPTR, $4
149 DATA _cgo_init+0(SB)/4, $x_cgo_init<>(SB)
150
View as plain text