Text file src/runtime/cgo/asm_unix_loong64.s

     1  // Copyright 2026 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && loong64
     6  
     7  #include "go_asm.h"
     8  #include "textflag.h"
     9  #include "abi_loong64.h"
    10  
    11  // cgoCallTrampoline is called by runtime.asmcgocall or runtime.asmcgocall_no_g
    12  // using the LoongArch LP64D C ABI with R4 pointing to a cgoCallFrame.
    13  TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
    14  	MOVV	R1, -16(R3)
    15  	ADDV	$-16, R3
    16  	MOVV	R1, 0(R3)
    17  	MOVV	R23, 8(R3)
    18  	MOVV	R4, R23
    19  	MOVV	cgoCallFrame_fn(R23), R12
    20  	MOVV	cgoCallFrame_a1(R23), R5
    21  	MOVV	cgoCallFrame_a2(R23), R6
    22  	MOVV	cgoCallFrame_a3(R23), R7
    23  	MOVV	cgoCallFrame_a4(R23), R8
    24  	MOVV	cgoCallFrame_a5(R23), R9
    25  	MOVV	cgoCallFrame_a0(R23), R4
    26  	JAL	(R12)
    27  	MOVV	R4, cgoCallFrame_r1(R23)
    28  	MOVV	R0, R4
    29  	MOVV	8(R3), R23
    30  	MOVV	0(R3), R1
    31  	ADDV	$16, R3
    32  	RET
    33  
    34  #define CGO_PROLOGUE \
    35  	ADDV	$(-24*8), R3; \
    36  	SAVE_R22_TO_R31(5*8); \
    37  	SAVE_F24_TO_F31(15*8); \
    38  	MOVV	R1, (23*8)(R3); \
    39  	MOVV	R0, g
    40  
    41  #define CGO_EPILOGUE \
    42  	RESTORE_R22_TO_R31(5*8); \
    43  	RESTORE_F24_TO_F31(15*8); \
    44  	MOVV	(23*8)(R3), R1; \
    45  	ADDV	$(24*8), R3
    46  
    47  // CALL_GO calls a Go function indirectly so that the linker's nosplit
    48  // check does not count the Go function's stack usage: these entrypoints
    49  // are only called from C, on a C stack, after CGO_PROLOGUE.
    50  #define CALL_GO(fn) \
    51  	MOVV	$fn(SB), R20; \
    52  	JAL	(R20)
    53  
    54  TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
    55  	MOVV	$·runtime_init_done(SB), R12
    56  	MOVW	(R12), R12
    57  	MOVV	$2, R13
    58  	BNE	R12, R13, slow
    59  	// Make the load of runtime_init_done an acquire load.
    60  	DBAR
    61  	MOVV	$·cgo_context_function(SB), R4
    62  	MOVV	(R4), R4
    63  	BNE	R4, R0, slow
    64  	RET
    65  slow:
    66  	CGO_PROLOGUE
    67  	CALL_GO(·cgoWaitRuntimeInitDone)
    68  	MOVV	8(R3), R4
    69  	CGO_EPILOGUE
    70  	RET
    71  
    72  TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
    73  	BEQ	R4, R0, done
    74  	CGO_PROLOGUE
    75  	MOVV	R4, 8(R3)
    76  	CALL_GO(·cgoReleaseContext)
    77  	CGO_EPILOGUE
    78  done:
    79  	RET
    80  
    81  TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
    82  	MOVV	R4, R5
    83  	MOVV	R0, R4
    84  	MOVV	R0, R7
    85  	JMP	crosscall2(SB)
    86  
    87  TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
    88  	CGO_PROLOGUE
    89  	MOVV	R4, 8(R3)
    90  	CALL_GO(·threadentry)
    91  	CGO_EPILOGUE
    92  	MOVV	R0, R4
    93  	RET
    94  
    95  TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
    96  	CGO_PROLOGUE
    97  	MOVV	R4, 8(R3)
    98  	MOVV	R5, 16(R3)
    99  	MOVV	R6, 24(R3)
   100  	MOVV	R7, 32(R3)
   101  	CALL_GO(·cgoInit)
   102  	CGO_EPILOGUE
   103  	RET
   104  GLOBL _cgo_init(SB), NOPTR, $8
   105  DATA _cgo_init+0(SB)/8, $x_cgo_init<>(SB)
   106  
   107  // x_cgo_callers is jumped to from runtime.cgoSigtramp on the signal stack.
   108  TEXT ·x_cgo_callers(SB),NOSPLIT|NOFRAME,$0
   109  	ADDV	$-80, R3
   110  	MOVV	g, 64(R3)		// save fp (R22/g)
   111  	MOVV	R1, 72(R3)
   112  	ADDV	$80, R3, g
   113  
   114  	MOVV	R0, 0(R3)		// arg.context = 0
   115  	MOVV	R6, 8(R3)		// arg.sigContext = context
   116  	MOVV	R8, 16(R3)		// arg.buf = cgoCallers
   117  	MOVV	$32, R12
   118  	MOVV	R12, 24(R3)		// arg.max = 32
   119  
   120  	MOVV	R4, 32(R3)		// save sig
   121  	MOVV	R5, 40(R3)		// save info
   122  	MOVV	R6, 48(R3)		// save context
   123  	MOVV	R9, 56(R3)		// save sigtramp
   124  
   125  	MOVV	R3, R4			// &arg
   126  	JAL	(R7)			// (*cgoTraceback)(&arg)
   127  
   128  	MOVV	32(R3), R4		// restore sig
   129  	MOVV	40(R3), R5		// restore info
   130  	MOVV	48(R3), R6		// restore context
   131  	MOVV	56(R3), R12		// restore sigtramp
   132  
   133  	MOVV	64(R3), g
   134  	MOVV	72(R3), R1
   135  	ADDV	$80, R3
   136  	JMP	(R12)			// sigtramp(sig, info, context)
   137  
   138  GLOBL _cgo_callers(SB), NOPTR, $8
   139  DATA _cgo_callers+0(SB)/8, $·x_cgo_callers(SB)
   140  

View as plain text