Text file
src/runtime/cgo/asm_unix_mips64x.s
1 // Copyright 2026 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && (mips64 || mips64le)
6
7 #include "go_asm.h"
8 #include "textflag.h"
9
10 // cgoCallTrampoline is called on the system stack by runtime.asmcgocall with
11 // a *cgoCallFrame in R4 using the MIPS N64 C ABI.
12 TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
13 MOVV R31, -32(R29)
14 ADDV $-32, R29
15 MOVV R31, 0(R29)
16 MOVV R16, 8(R29)
17 MOVV RSB, 16(R29)
18 MOVV R4, R16
19 MOVV cgoCallFrame_fn(R16), R25
20 MOVV cgoCallFrame_a0(R16), R4
21 MOVV cgoCallFrame_a1(R16), R5
22 MOVV cgoCallFrame_a2(R16), R6
23 MOVV cgoCallFrame_a3(R16), R7
24 MOVV cgoCallFrame_a4(R16), R8
25 MOVV cgoCallFrame_a5(R16), R9
26 JAL (R25)
27 MOVV R2, cgoCallFrame_r1(R16)
28 MOVV R0, R2
29 MOVV 16(R29), RSB
30 MOVV 8(R29), R16
31 MOVV 0(R29), R31
32 ADDV $32, R29
33 RET
34
35 #ifndef GOMIPS64_softfloat
36 #define CGO_PROLOGUE \
37 ADDV $(-8*24), R29; \
38 MOVV R16, (8*5)(R29); \
39 MOVV R17, (8*6)(R29); \
40 MOVV R18, (8*7)(R29); \
41 MOVV R19, (8*8)(R29); \
42 MOVV R20, (8*9)(R29); \
43 MOVV R21, (8*10)(R29); \
44 MOVV R22, (8*11)(R29); \
45 MOVV R23, (8*12)(R29); \
46 MOVV RSB, (8*13)(R29); \
47 MOVV g, (8*14)(R29); \
48 MOVV R31, (8*15)(R29); \
49 MOVD F24, (8*16)(R29); \
50 MOVD F25, (8*17)(R29); \
51 MOVD F26, (8*18)(R29); \
52 MOVD F27, (8*19)(R29); \
53 MOVD F28, (8*20)(R29); \
54 MOVD F29, (8*21)(R29); \
55 MOVD F30, (8*22)(R29); \
56 MOVD F31, (8*23)(R29); \
57 BGEZAL R0, 1(PC); \
58 SRLV $32, R31, RSB; \
59 SLLV $32, RSB; \
60 MOVV R0, g
61
62 #define CGO_EPILOGUE \
63 MOVD (8*16)(R29), F24; \
64 MOVD (8*17)(R29), F25; \
65 MOVD (8*18)(R29), F26; \
66 MOVD (8*19)(R29), F27; \
67 MOVD (8*20)(R29), F28; \
68 MOVD (8*21)(R29), F29; \
69 MOVD (8*22)(R29), F30; \
70 MOVD (8*23)(R29), F31; \
71 MOVV (8*5)(R29), R16; \
72 MOVV (8*6)(R29), R17; \
73 MOVV (8*7)(R29), R18; \
74 MOVV (8*8)(R29), R19; \
75 MOVV (8*9)(R29), R20; \
76 MOVV (8*10)(R29), R21; \
77 MOVV (8*11)(R29), R22; \
78 MOVV (8*12)(R29), R23; \
79 MOVV (8*13)(R29), RSB; \
80 MOVV (8*14)(R29), g; \
81 MOVV (8*15)(R29), R31; \
82 ADDV $(8*24), R29
83 #else
84 #define CGO_PROLOGUE \
85 ADDV $(-8*16), R29; \
86 MOVV R16, (8*5)(R29); \
87 MOVV R17, (8*6)(R29); \
88 MOVV R18, (8*7)(R29); \
89 MOVV R19, (8*8)(R29); \
90 MOVV R20, (8*9)(R29); \
91 MOVV R21, (8*10)(R29); \
92 MOVV R22, (8*11)(R29); \
93 MOVV R23, (8*12)(R29); \
94 MOVV RSB, (8*13)(R29); \
95 MOVV g, (8*14)(R29); \
96 MOVV R31, (8*15)(R29); \
97 BGEZAL R0, 1(PC); \
98 SRLV $32, R31, RSB; \
99 SLLV $32, RSB; \
100 MOVV R0, g
101
102 #define CGO_EPILOGUE \
103 MOVV (8*5)(R29), R16; \
104 MOVV (8*6)(R29), R17; \
105 MOVV (8*7)(R29), R18; \
106 MOVV (8*8)(R29), R19; \
107 MOVV (8*9)(R29), R20; \
108 MOVV (8*10)(R29), R21; \
109 MOVV (8*11)(R29), R22; \
110 MOVV (8*12)(R29), R23; \
111 MOVV (8*13)(R29), RSB; \
112 MOVV (8*14)(R29), g; \
113 MOVV (8*15)(R29), R31; \
114 ADDV $(8*16), R29
115 #endif
116
117 TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
118 MOVV RSB, R14
119 MOVV R31, R15
120 BGEZAL R0, 1(PC)
121 SRLV $32, R31, RSB
122 SLLV $32, RSB
123 MOVV R15, R31
124 MOVV $·runtime_init_done(SB), R12
125 MOVW (R12), R12
126 MOVV $2, R13
127 BNE R12, R13, slow
128 // Make the load of runtime_init_done an acquire load.
129 SYNC
130 MOVV $·cgo_context_function(SB), R2
131 MOVV (R2), R2
132 BNE R2, R0, slow
133 MOVV R14, RSB
134 RET
135 slow:
136 MOVV R14, RSB
137 CGO_PROLOGUE
138 JAL ·cgoWaitRuntimeInitDone(SB)
139 MOVV 8(R29), R2
140 CGO_EPILOGUE
141 RET
142
143 TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
144 BEQ R4, done
145 CGO_PROLOGUE
146 MOVV R4, 8(R29)
147 JAL ·cgoReleaseContext(SB)
148 CGO_EPILOGUE
149 done:
150 RET
151
152 TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
153 MOVV R4, R5
154 MOVV R0, R4
155 MOVV R0, R7
156 JMP crosscall2(SB)
157
158 TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
159 CGO_PROLOGUE
160 MOVV R4, 8(R29)
161 JAL ·threadentry(SB)
162 CGO_EPILOGUE
163 MOVV R0, R2
164 RET
165
166 TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
167 CGO_PROLOGUE
168 MOVV R4, 8(R29)
169 MOVV R5, 16(R29)
170 MOVV R6, 24(R29)
171 MOVV R7, 32(R29)
172 JAL ·cgoInit(SB)
173 CGO_EPILOGUE
174 RET
175 GLOBL _cgo_init(SB), NOPTR, $8
176 DATA _cgo_init+0(SB)/8, $x_cgo_init<>(SB)
177
View as plain text