Text file
src/runtime/cgo/asm_unix_mipsx.s
1 // Copyright 2026 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && (mips || mipsle)
6
7 #include "go_asm.h"
8 #include "textflag.h"
9
10 // cgoCallTrampoline is called on the system stack by runtime.asmcgocall with
11 // a *cgoCallFrame in R4 using the MIPS O32 C ABI.
12 // Note: O32 requires the caller to reserve 0(R29)..15(R29) as the callee's
13 // argument home area, so LR cannot be stored at 0(R29) across the C call.
14 // runtime.asmcgocall and runtime.asmcgocall_no_g align R29 to 8 bytes.
15 TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
16 ADDU $-40, R29
17 MOVW R16, 24(R29)
18 MOVW R28, 28(R29)
19 MOVW R31, 32(R29)
20 MOVW R4, R16
21 MOVW cgoCallFrame_fn(R16), R25
22 MOVW cgoCallFrame_a0(R16), R4
23 MOVW cgoCallFrame_a1(R16), R5
24 MOVW cgoCallFrame_a2(R16), R6
25 MOVW cgoCallFrame_a3(R16), R7
26 MOVW cgoCallFrame_a4(R16), R8
27 MOVW cgoCallFrame_a5(R16), R9
28 MOVW R8, 16(R29)
29 MOVW R9, 20(R29)
30 JAL (R25)
31 MOVW R2, cgoCallFrame_r1(R16)
32 MOVW R0, R2
33 MOVW 32(R29), R31
34 MOVW 28(R29), R28
35 MOVW 24(R29), R16
36 ADDU $40, R29
37 RET
38
39 #ifndef GOMIPS_softfloat
40 #define CGO_PROLOGUE \
41 ADDU $-112, R29; \
42 MOVW R16, 20(R29); \
43 MOVW R17, 24(R29); \
44 MOVW R18, 28(R29); \
45 MOVW R19, 32(R29); \
46 MOVW R20, 36(R29); \
47 MOVW R21, 40(R29); \
48 MOVW R22, 44(R29); \
49 MOVW R23, 48(R29); \
50 MOVW R28, 52(R29); \
51 MOVW g, 56(R29); \
52 MOVW R31, 60(R29); \
53 MOVD F20, 64(R29); \
54 MOVD F22, 72(R29); \
55 MOVD F24, 80(R29); \
56 MOVD F26, 88(R29); \
57 MOVD F28, 96(R29); \
58 MOVD F30, 104(R29); \
59 MOVW R0, g
60
61 #define CGO_EPILOGUE \
62 MOVD 64(R29), F20; \
63 MOVD 72(R29), F22; \
64 MOVD 80(R29), F24; \
65 MOVD 88(R29), F26; \
66 MOVD 96(R29), F28; \
67 MOVD 104(R29), F30; \
68 MOVW 20(R29), R16; \
69 MOVW 24(R29), R17; \
70 MOVW 28(R29), R18; \
71 MOVW 32(R29), R19; \
72 MOVW 36(R29), R20; \
73 MOVW 40(R29), R21; \
74 MOVW 44(R29), R22; \
75 MOVW 48(R29), R23; \
76 MOVW 52(R29), R28; \
77 MOVW 56(R29), g; \
78 MOVW 60(R29), R31; \
79 ADDU $112, R29
80 #else
81 #define CGO_PROLOGUE \
82 ADDU $-64, R29; \
83 MOVW R16, 20(R29); \
84 MOVW R17, 24(R29); \
85 MOVW R18, 28(R29); \
86 MOVW R19, 32(R29); \
87 MOVW R20, 36(R29); \
88 MOVW R21, 40(R29); \
89 MOVW R22, 44(R29); \
90 MOVW R23, 48(R29); \
91 MOVW R28, 52(R29); \
92 MOVW g, 56(R29); \
93 MOVW R31, 60(R29); \
94 MOVW R0, g
95
96 #define CGO_EPILOGUE \
97 MOVW 20(R29), R16; \
98 MOVW 24(R29), R17; \
99 MOVW 28(R29), R18; \
100 MOVW 32(R29), R19; \
101 MOVW 36(R29), R20; \
102 MOVW 40(R29), R21; \
103 MOVW 44(R29), R22; \
104 MOVW 48(R29), R23; \
105 MOVW 52(R29), R28; \
106 MOVW 56(R29), g; \
107 MOVW 60(R29), R31; \
108 ADDU $64, R29
109 #endif
110
111 TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
112 MOVW $·runtime_init_done(SB), R8
113 MOVW (R8), R8
114 MOVW $2, R9
115 BNE R8, R9, slow
116 // Make the load of runtime_init_done an acquire load.
117 SYNC
118 MOVW $·cgo_context_function(SB), R2
119 MOVW (R2), R2
120 BNE R2, R0, slow
121 RET
122 slow:
123 CGO_PROLOGUE
124 JAL ·cgoWaitRuntimeInitDone(SB)
125 MOVW 4(R29), R2
126 CGO_EPILOGUE
127 RET
128
129 TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
130 BEQ R4, done
131 CGO_PROLOGUE
132 MOVW R4, 4(R29)
133 JAL ·cgoReleaseContext(SB)
134 CGO_EPILOGUE
135 done:
136 RET
137
138 TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
139 MOVW R4, R5
140 MOVW R0, R4
141 MOVW R0, R7
142 JMP crosscall2(SB)
143
144 TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
145 CGO_PROLOGUE
146 MOVW R4, 4(R29)
147 JAL ·threadentry(SB)
148 CGO_EPILOGUE
149 MOVW R0, R2
150 RET
151
152 TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
153 CGO_PROLOGUE
154 MOVW R4, 4(R29)
155 MOVW R5, 8(R29)
156 MOVW R6, 12(R29)
157 MOVW R7, 16(R29)
158 JAL ·cgoInit(SB)
159 CGO_EPILOGUE
160 RET
161 GLOBL _cgo_init(SB), NOPTR, $4
162 DATA _cgo_init+0(SB)/4, $x_cgo_init<>(SB)
163
View as plain text