Text file
src/runtime/cgo/asm_unix_ppc64x.s
1 // Copyright 2026 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && (ppc64 || ppc64le)
6
7 #include "go_asm.h"
8 #include "textflag.h"
9 #include "asm_ppc64x.h"
10 #include "abi_ppc64x.h"
11
12 #ifdef GO_PPC64X_HAS_FUNCDESC
13 // On AIX (XCOFF), C function pointers are 24-byte descriptors, and the frame
14 // provides the 48-byte AIX linkage area (TOC at 40(R1)) plus 64-byte parameter
15 // save area before local save slots at 112(R1). As in runtime's
16 // callCfunction<>, cgoCallFrame.fn is the address of a TOC entry holding the
17 // function descriptor's address, as the address of a dynamic import is.
18 DEFINE_PPC64X_FUNCDESC(·cgoCallTrampoline, _cgoCallTrampoline<>)
19 TEXT _cgoCallTrampoline<>(SB),NOSPLIT|NOFRAME,$0-0
20 // Save LR in the AIX LR save slot of the caller's frame, then
21 // allocate the frame and store the back-chain pointer at 0(R1).
22 MOVD LR, R0
23 MOVD R0, 16(R1)
24 MOVDU R1, -128(R1)
25 XOR R0, R0
26 MOVD R2, 40(R1)
27 MOVD R14, 112(R1)
28 MOVD R3, R14
29 MOVD cgoCallFrame_fn(R14), R12
30 MOVD 0(R12), R12
31 MOVD 0(R12), R0
32 MOVD 8(R12), R2
33 MOVD 16(R12), R11
34 MOVD R0, CTR
35 MOVD cgoCallFrame_a0(R14), R3
36 MOVD cgoCallFrame_a1(R14), R4
37 MOVD cgoCallFrame_a2(R14), R5
38 MOVD cgoCallFrame_a3(R14), R6
39 MOVD cgoCallFrame_a4(R14), R7
40 MOVD cgoCallFrame_a5(R14), R8
41 BL (CTR)
42 XOR R0, R0
43 MOVD 40(R1), R2
44 MOVD R3, cgoCallFrame_r1(R14)
45 MOVD $0, R3
46 MOVD 112(R1), R14
47 MOVD 144(R1), R0
48 MOVD R0, LR
49 XOR R0, R0
50 ADD $128, R1
51 RET
52 #else
53 // cgoCallTrampoline is called by runtime.asmcgocall or runtime.asmcgocall_no_g
54 // using the PowerPC64 ELFv2 C ABI with R3 pointing to a cgoCallFrame.
55 // The frame includes the 32-byte linkage area and 64-byte parameter save area
56 // required by variadic C functions.
57 TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
58 // Save LR in the ELFv2 LR save slot of the caller's frame, then
59 // allocate the frame and store the back-chain pointer at 0(R1).
60 MOVD LR, R0
61 MOVD R0, 16(R1)
62 MOVDU R1, -112(R1)
63 XOR R0, R0
64 MOVD R2, 24(R1)
65 MOVD R14, 96(R1)
66 MOVD R3, R14
67 MOVD cgoCallFrame_fn(R14), R12
68 MOVD R12, CTR
69 MOVD cgoCallFrame_a0(R14), R3
70 MOVD cgoCallFrame_a1(R14), R4
71 MOVD cgoCallFrame_a2(R14), R5
72 MOVD cgoCallFrame_a3(R14), R6
73 MOVD cgoCallFrame_a4(R14), R7
74 MOVD cgoCallFrame_a5(R14), R8
75 BL (CTR)
76 XOR R0, R0
77 MOVD 24(R1), R2
78 MOVD R3, cgoCallFrame_r1(R14)
79 MOVD $0, R3
80 MOVD 96(R1), R14
81 MOVD 128(R1), R0
82 MOVD R0, LR
83 XOR R0, R0
84 ADD $112, R1
85 RET
86 #endif
87
88 #define CGO_PROLOGUE \
89 STACK_AND_SAVE_HOST_TO_GO_ABI(32); \
90 MOVD R2, 24(R1); \
91 MOVD $0, g
92
93 #define CGO_EPILOGUE \
94 MOVD 24(R1), R2; \
95 UNSTACK_AND_RESTORE_GO_TO_HOST_ABI(32)
96
97 // Indirectly call Go targets via CTR to avoid the linker's static NOSPLIT
98 // stack overflow check: these entrypoints are only invoked from C on a
99 // full-size C/pthread stack after saving 544 bytes of host registers.
100 #define CALL_GO(fn) \
101 MOVD $fn(SB), R12; \
102 MOVD R12, CTR; \
103 BL (CTR)
104
105 TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
106 MOVD $·runtime_init_done(SB), R4
107 MOVWZ (R4), R4
108 CMPW R4, $2
109 BNE slow
110 // Make the load of runtime_init_done an acquire load.
111 LWSYNC
112 MOVD $·cgo_context_function(SB), R3
113 MOVD (R3), R3
114 CMP R3, $0
115 BNE slow
116 RET
117 slow:
118 CGO_PROLOGUE
119 CALL_GO(·cgoWaitRuntimeInitDone)
120 MOVD FIXED_FRAME+0(R1), R3
121 CGO_EPILOGUE
122 RET
123
124 TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
125 CMP R3, $0
126 BEQ done
127 CGO_PROLOGUE
128 MOVD R3, FIXED_FRAME+0(R1)
129 CALL_GO(·cgoReleaseContext)
130 CGO_EPILOGUE
131 done:
132 RET
133
134 #ifdef GO_PPC64X_HAS_FUNCDESC
135 DEFINE_PPC64X_FUNCDESC(·pthreadKeyDestructor, _pthreadKeyDestructor<>)
136 TEXT _pthreadKeyDestructor<>(SB),NOSPLIT|NOFRAME,$0-0
137 #else
138 TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
139 #endif
140 MOVD R3, R4
141 MOVD $0, R3
142 MOVD $0, R6
143 JMP crosscall2(SB)
144
145 #ifdef GO_PPC64X_HAS_FUNCDESC
146 DEFINE_PPC64X_FUNCDESC(·x_cgo_threadentry, _x_cgo_threadentry<>)
147 TEXT _x_cgo_threadentry<>(SB),NOSPLIT|NOFRAME,$0-0
148 #else
149 TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
150 #endif
151 CGO_PROLOGUE
152 MOVD R3, FIXED_FRAME+0(R1)
153 CALL_GO(·threadentry)
154 CGO_EPILOGUE
155 MOVD $0, R3
156 RET
157
158 #ifdef GO_PPC64X_HAS_FUNCDESC
159 DEFINE_PPC64X_FUNCDESC(x_cgo_init_desc<>, x_cgo_init<>)
160 #endif
161 TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
162 CGO_PROLOGUE
163 MOVD R3, FIXED_FRAME+0(R1)
164 MOVD R4, FIXED_FRAME+8(R1)
165 // runtime.rt0_go does not pass the TLS arguments used by
166 // cgoInitTLS on Android; R5 and R6 hold unrelated values.
167 MOVD $0, R5
168 MOVD R5, FIXED_FRAME+16(R1)
169 MOVD R5, FIXED_FRAME+24(R1)
170 CALL_GO(·cgoInit)
171 CGO_EPILOGUE
172 RET
173 GLOBL _cgo_init(SB), NOPTR, $8
174 #ifdef GO_PPC64X_HAS_FUNCDESC
175 DATA _cgo_init+0(SB)/8, $x_cgo_init_desc<>(SB)
176 #else
177 DATA _cgo_init+0(SB)/8, $x_cgo_init<>(SB)
178
179 // x_cgo_callers is jumped to from runtime.cgoSigtramp on the signal stack.
180 TEXT ·x_cgo_callers(SB),NOSPLIT|NOFRAME,$0-0
181 MOVD LR, R0
182 MOVD R0, 16(R1)
183 MOVDU R1, -160(R1)
184 MOVD R2, 24(R1)
185 XOR R0, R0
186
187 MOVD R0, 96(R1) // arg.context = 0
188 MOVD R5, 104(R1) // arg.sigContext = context
189 MOVD R7, 112(R1) // arg.buf = cgoCallers
190 MOVD $32, R9
191 MOVD R9, 120(R1) // arg.max = 32
192
193 MOVD R3, 128(R1) // save sig
194 MOVD R4, 136(R1) // save info
195 MOVD R5, 144(R1) // save context
196 MOVD R8, 152(R1) // save sigtramp
197
198 ADD $96, R1, R3 // &arg
199 MOVD R6, R12
200 MOVD R12, CTR
201 BL (CTR) // (*cgoTraceback)(&arg)
202 XOR R0, R0
203 MOVD 24(R1), R2
204
205 MOVD 128(R1), R3 // restore sig
206 MOVD 136(R1), R4 // restore info
207 MOVD 144(R1), R5 // restore context
208 MOVD 152(R1), R12 // restore sigtramp
209
210 ADD $160, R1
211 MOVD 16(R1), R9
212 MOVD R9, LR
213 MOVD R12, CTR
214 JMP (CTR) // sigtramp(sig, info, context)
215
216 GLOBL _cgo_callers(SB), NOPTR, $8
217 DATA _cgo_callers+0(SB)/8, $·x_cgo_callers(SB)
218 #endif
219
220 #ifdef GOOS_aix
221 TEXT _cgo_topofstack(SB),NOSPLIT|NOFRAME,$0-0
222 MOVD $__cgo_topofstack(SB), R12
223 MOVD R12, CTR
224 BR (CTR)
225
226 TEXT _GLOBAL__I_65535_0_runtime_cgo(SB),NOSPLIT|NOFRAME,$0-0
227 MOVD $_rt0_ppc64_aix_lib(SB), R12
228 MOVD R12, CTR
229 BR (CTR)
230 #endif
231
View as plain text