Text file src/runtime/cgo/asm_unix_riscv64.s

     1  // Copyright 2026 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && riscv64
     6  
     7  #include "go_asm.h"
     8  #include "textflag.h"
     9  #include "abi_riscv64.h"
    10  
    11  // cgoCallTrampoline is called by runtime.asmcgocall or runtime.asmcgocall_no_g
    12  // using the RISC-V LP64D C ABI with X10 pointing to a cgoCallFrame.
    13  TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
    14  	// Call through T1 (X6), not T0 (X5): T0 is the alternate link
    15  	// register, so JALR RA, T0 tells the return-address predictor
    16  	// to pop an entry before pushing, as for a coroutine switch.
    17  	MOV	RA, -16(X2)
    18  	ADD	$-16, X2
    19  	MOV	RA, 0(X2)
    20  	MOV	X9, 8(X2)
    21  	MOV	X10, X9
    22  	MOV	cgoCallFrame_fn(X9), X6
    23  	MOV	cgoCallFrame_a1(X9), X11
    24  	MOV	cgoCallFrame_a2(X9), X12
    25  	MOV	cgoCallFrame_a3(X9), X13
    26  	MOV	cgoCallFrame_a4(X9), X14
    27  	MOV	cgoCallFrame_a5(X9), X15
    28  	MOV	cgoCallFrame_a0(X9), X10
    29  	JALR	RA, X6
    30  	MOV	X10, cgoCallFrame_r1(X9)
    31  	MOV	ZERO, X10
    32  	MOV	0(X2), RA
    33  	MOV	8(X2), X9
    34  	ADD	$16, X2
    35  	RET
    36  
    37  #define CGO_PROLOGUE \
    38  	ADD	$(-30*8), X2; \
    39  	SAVE_GPR(5*8); \
    40  	MOV	X1, (17*8)(X2); \
    41  	SAVE_FPR(18*8); \
    42  	MOV	ZERO, g
    43  
    44  #define CGO_EPILOGUE \
    45  	RESTORE_GPR(5*8); \
    46  	MOV	(17*8)(X2), X1; \
    47  	RESTORE_FPR(18*8); \
    48  	ADD	$(30*8), X2
    49  
    50  // CALL_GO calls a Go function indirectly so that the linker's nosplit
    51  // check does not count the Go function's stack usage: these entrypoints
    52  // are only called from C, on a C stack, after CGO_PROLOGUE.
    53  #define CALL_GO(fn) \
    54  	MOV	$fn(SB), X6; \
    55  	JALR	RA, X6
    56  
    57  TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
    58  	MOV	$·runtime_init_done(SB), X5
    59  	MOVW	(X5), X5
    60  	MOV	$2, X6
    61  	BNE	X5, X6, slow
    62  	// Make the load of runtime_init_done an acquire load.
    63  	FENCE
    64  	MOV	$·cgo_context_function(SB), X10
    65  	MOV	(X10), X10
    66  	BNE	X10, ZERO, slow
    67  	RET
    68  slow:
    69  	CGO_PROLOGUE
    70  	CALL_GO(·cgoWaitRuntimeInitDone)
    71  	MOV	8(X2), X10
    72  	CGO_EPILOGUE
    73  	RET
    74  
    75  TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
    76  	BEQ	X10, ZERO, done
    77  	CGO_PROLOGUE
    78  	MOV	X10, 8(X2)
    79  	CALL_GO(·cgoReleaseContext)
    80  	CGO_EPILOGUE
    81  done:
    82  	RET
    83  
    84  TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
    85  	MOV	X10, X11
    86  	MOV	ZERO, X10
    87  	MOV	ZERO, X13
    88  	JMP	crosscall2(SB)
    89  
    90  TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
    91  	CGO_PROLOGUE
    92  	MOV	X10, 8(X2)
    93  	CALL_GO(·threadentry)
    94  	CGO_EPILOGUE
    95  	MOV	ZERO, X10
    96  	RET
    97  
    98  TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
    99  	CGO_PROLOGUE
   100  	MOV	X10, 8(X2)
   101  	MOV	X11, 16(X2)
   102  	MOV	X12, 24(X2)
   103  	MOV	X13, 32(X2)
   104  	CALL_GO(·cgoInit)
   105  	CGO_EPILOGUE
   106  	RET
   107  GLOBL _cgo_init(SB), NOPTR, $8
   108  DATA _cgo_init+0(SB)/8, $x_cgo_init<>(SB)
   109  

View as plain text