Text file
src/runtime/cgo/asm_unix_s390x.s
1 // Copyright 2026 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 //go:build goexperiment.runtimecgopurego && !msan && !tsan && unix && s390x
6
7 #include "go_asm.h"
8 #include "textflag.h"
9
10 // cgoCallTrampoline is called on the system stack by runtime.asmcgocall with
11 // a *cgoCallFrame in R2 using the Linux z/Architecture ELF ABI.
12 TEXT ·cgoCallTrampoline(SB),NOSPLIT|NOFRAME,$0-0
13 STMG R6, R14, 48(R15)
14 MOVD R2, R10
15 MOVD R14, -168(R15)
16 ADD $-168, R15
17 MOVD R14, 0(R15)
18 MOVD cgoCallFrame_fn(R10), R1
19 MOVD cgoCallFrame_a0(R10), R2
20 MOVD cgoCallFrame_a1(R10), R3
21 MOVD cgoCallFrame_a2(R10), R4
22 MOVD cgoCallFrame_a3(R10), R5
23 MOVD cgoCallFrame_a4(R10), R6
24 MOVD cgoCallFrame_a5(R10), R7
25 MOVD R7, 160(R15)
26 BL R1
27 XOR R0, R0
28 MOVD R2, cgoCallFrame_r1(R10)
29 MOVD $0, R2
30 MOVD 0(R15), R14
31 ADD $168, R15
32 LMG 48(R15), R6, R14
33 RET
34
35 #define CGO_PROLOGUE \
36 STMG R6, R14, 48(R15); \
37 ADD $-104, R15; \
38 FMOVD F8, 40(R15); \
39 FMOVD F9, 48(R15); \
40 FMOVD F10, 56(R15); \
41 FMOVD F11, 64(R15); \
42 FMOVD F12, 72(R15); \
43 FMOVD F13, 80(R15); \
44 FMOVD F14, 88(R15); \
45 FMOVD F15, 96(R15); \
46 XOR R0, R0; \
47 MOVD $0, g
48
49 #define CGO_EPILOGUE \
50 FMOVD 40(R15), F8; \
51 FMOVD 48(R15), F9; \
52 FMOVD 56(R15), F10; \
53 FMOVD 64(R15), F11; \
54 FMOVD 72(R15), F12; \
55 FMOVD 80(R15), F13; \
56 FMOVD 88(R15), F14; \
57 FMOVD 96(R15), F15; \
58 ADD $104, R15; \
59 LMG 48(R15), R6, R14
60
61 // CALL_GO calls a Go function indirectly so that the linker's nosplit
62 // check does not count the Go function's stack usage: these entrypoints
63 // are only called from C, on a C stack, after CGO_PROLOGUE.
64 #define CALL_GO(fn) \
65 MOVD $fn(SB), R1; \
66 BL R1
67
68 TEXT _cgo_wait_runtime_init_done(SB),NOSPLIT|NOFRAME,$0-0
69 MOVD $·runtime_init_done(SB), R1
70 MOVWZ (R1), R1
71 CMPW R1, $2
72 BNE slow
73 MOVD $·cgo_context_function(SB), R2
74 MOVD (R2), R2
75 CMPBNE R2, $0, slow
76 RET
77 slow:
78 CGO_PROLOGUE
79 CALL_GO(·cgoWaitRuntimeInitDone)
80 MOVD 8(R15), R2
81 CGO_EPILOGUE
82 RET
83
84 TEXT _cgo_release_context(SB),NOSPLIT|NOFRAME,$0-0
85 CMPBEQ R2, $0, done
86 CGO_PROLOGUE
87 MOVD R2, 8(R15)
88 CALL_GO(·cgoReleaseContext)
89 CGO_EPILOGUE
90 done:
91 RET
92
93 TEXT ·pthreadKeyDestructor(SB),NOSPLIT|NOFRAME,$0-0
94 MOVD R2, R3
95 MOVD $0, R2
96 MOVD $0, R5
97 JMP crosscall2(SB)
98
99 TEXT ·x_cgo_threadentry(SB),NOSPLIT|NOFRAME,$0-0
100 CGO_PROLOGUE
101 MOVD R2, 8(R15)
102 CALL_GO(·threadentry)
103 CGO_EPILOGUE
104 MOVD $0, R2
105 RET
106
107 TEXT x_cgo_init<>(SB),NOSPLIT|NOFRAME,$0-0
108 CGO_PROLOGUE
109 MOVD R2, 8(R15)
110 MOVD R3, 16(R15)
111 // runtime.rt0_go does not pass the TLS arguments used by
112 // cgoInitTLS on Android; R4 and R5 hold unrelated values.
113 MOVD $0, 24(R15)
114 MOVD $0, 32(R15)
115 CALL_GO(·cgoInit)
116 CGO_EPILOGUE
117 RET
118 GLOBL _cgo_init(SB), NOPTR, $8
119 DATA _cgo_init+0(SB)/8, $x_cgo_init<>(SB)
120
View as plain text